Reality Factory

Code: Select all

Pawn Type: robot
Script Name: robot.s
Spawn Order: Spawn
szentityname: robot

Code: Select all

{
	IDLE			[idle]
	WALK			[walk]
	RUN			[walk]

	FOV			[160]
	SIGHTDIST		[1000]
	YAWSPEED		[70]
	WALKSPEED		[30]
	SCALE			[1.7]
	DAMAGEATTRIBUTE		[health]
	TELEPORTTARGET		[Rezpoint1] // or whatever the name of the ScriptPoint...
	SW			[0]
	SH			[0]
	

	Start[ ()
	{	
		// Console(true);	
		SetFOV(FOV);					// set field of view
		BoxWidth(50);
		FindTargetOrder(SIGHTDIST, "FoundTarget", DAMAGEATTRIBUTE);	// seen a target to chase
		RotateToPoint(IDLE, YAWSPEED, false, ""); 	// go to point if any specified
		MoveToPoint(WALK, WALKSPEED*SCALE, "");		// move to starting point	
		NewOrder("Guard");
	} ]

	
	Patrol[ ()
	{	
		// patroling from point to point, looking for special orders in each script point (i.e. "Guard")
		NextPoint(); 
		NextOrder();	
		RotateToPoint(IDLE, YAWSPEED, false, "");
		MoveToPoint(WALK, WALKSPEED*SCALE, "");			
		RestartOrder();
	} ]
	
	Guard[()
	{
		// just look around a bit
		Rotate(IDLE, YAWSPEED, 0, -160, 0, "");  
		Delay(IDLE, random(3,5), "");
		Rotate(IDLE, YAWSPEED, 0, 160, 0, "");
		Delay(IDLE, random(3,5), "");
		Align();
		NewOrder("Patrol"); // continue to patrol
	}]
	
	FoundTarget[ ()
	{
		// target discovered
		SetKeyPause(true); 		// disable keyboard
		RotateToPlayer(IDLE, YAWSPEED, false, "");
		LowLevel("camera");
		
	}]
	
	camera[()
	{		
		// place the camera behind the pawn so the player can see who found him
		SW = GetScreenWidth()/2;
            	SH = GetScreenHeight()/2;
            	AttachCamera(); 
		TiltCamera(ConvertDegrees(20));
		HighLevel("ViewTarget");
	}]

	ViewTarget[()
	{
		// just look at the player
		ShowTextDelay(0, "", IDLE, "<Player><CR>You were discovered", 12, 5, "", SW, SH, "center", 255); 
		LowLevel("forbidden");
	} ]

	forbidden[()
	{	
		// move player to TELEPORTTARGET
		DetachCamera(); // return camera to player
		TeleportEntity("Player", TELEPORTTARGET, 64, 0, 0, true);		
		// name of the 1st scriptpoint in the path is equal to the seven leftmost characters of the pawn's name
		POINTNAME=LeftCopy(self.EntityName, 7); 
		TeleportEntity(self.EntityName, POINTNAME, 0, 0, 0, true); // move the pawn to the 1st scriptpoint 
		NewPoint(POINTNAME);HighLevel("Continue");
	} ]
	
	Continue[()
	{
		SetKeyPause(false); // re-enable keys
		FindTargetOrder(SIGHTDIST, "FoundTarget", DAMAGEATTRIBUTE); // re-activate target order
		NewOrder("Guard"); 
	}]
}